<!-- getStage.xsl: copy all schema elements with either no sn:stages
attribute or else an sn:stages element with the passed stage name as a
value to another schema.

Bob DuCharme 6/4/02 Use at your own risk, no warrantee expressed or implied. 

Revised 10/2/02 to incorporate David McNally's suggestion to use contains() to
look for " $stageName " in a space-delimited list of names instead of using an
XSLT processor's tokenize() extension.

-->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:sn="http://www.snee.com/ns/stages"
                version="1.0">

  <xsl:param name="stageName">NoName</xsl:param>

  <xsl:key name="stageKey" match="sn:stages/sn:stage" use="@name"/>


  <xsl:template match="/">


    <!-- Two checks to make sure we're ready to proceed. -->

    <xsl:if test="$stageName = 'NoName'">
      <xsl:message terminate="yes">
Stage name must be passed as a parameter.
      </xsl:message>
    </xsl:if>

    <xsl:if test="not(key('stageKey',$stageName)/@name)">
      <xsl:message terminate="yes">
'<xsl:value-of select="$stageName"/>' not defined as a stage name in master schema.
      </xsl:message>
    </xsl:if>


    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>

  </xsl:template>


  <xsl:template match="*">

      <!-- If no specific stages are specified, copy the element. -->

      <xsl:if test="not(@sn:stages)">
        <xsl:copy>
          <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
      </xsl:if>


      <!-- If this element's list of stage names includes the one we want,
           copy this element to the result tree. -->

      <xsl:if test="contains(concat(' ',normalize-space(@sn:stages),' '),
                    concat('',$stageName,' '))">
        <xsl:copy>
          <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
      </xsl:if>

  </xsl:template>


  <xsl:template match="@*|comment()|processing-instruction()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>


  <!-- Don't need these outside of the master version. -->
  <xsl:template match="sn:stages | @sn:stages"/>

</xsl:stylesheet>